Форум по Роботика

Контролери => Ардуино (Arduino) => Темата е започната от: tonivox в Февруари 08, 2012, 10:01:59 am

Титла: Arduino Real Time
Публикувано от: tonivox в Февруари 08, 2012, 10:01:59 am

Здравейте колеги :) Имам едно въпросче към вас. Искам да си направя часовник инициализиран на дисплей с Ардуино. Сглобих си модула с DS1307 но нито един от кодовете в интернет не сработиха. Ако някой е правил нещо подобно моля да помогне. Благодаря предварително :)

Титла: Гарантирам,че работи.
Публикувано от: reverenge в Февруари 08, 2012, 09:23:37 pm

//
// Maurice Ribble
// 4-17-2008
// http://www.glacialwanderer.com/hobbyrobotics

// This code tests the DS1307 Real Time clock on the Arduino board.
// The ds1307 works in binary coded decimal or BCD.  You can look up
// bcd in google if you aren't familior with it.  There can output
// a square wave, but I don't expose that in this code.  See the
// ds1307 for it's full capabilities.

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68

// Convert normal decimal numbers to binary coded decimal
byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}

// Convert binary coded decimal to normal decimal numbers
byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

// Stops the DS1307, but it has the side effect of setting seconds to 0
// Probably only want to use this for testing
/*void stopDs1307()
{
  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.send(0);
  Wire.send(0x80);
  Wire.endTransmission();
}*/

// 1) Sets the date and time on the ds1307
// 2) Starts the clock
// 3) Sets hour mode to 24 hour clock
// Assumes you're passing in valid numbers
void setDateDs1307(byte second,        // 0-59
                   byte minute,        // 0-59
                   byte hour,          // 1-23
                   byte dayOfWeek,     // 1-7
                   byte dayOfMonth,    // 1-28/29/30/31
                   byte month,         // 1-12
                   byte year)          // 0-99
{
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.send(0);
   Wire.send(decToBcd(second));    // 0 to bit 7 starts the clock
   Wire.send(decToBcd(minute));
   Wire.send(decToBcd(hour));      // If you want 12 hour am/pm you need to set
                                   // bit 6 (also need to change readDateDs1307)
   Wire.send(decToBcd(dayOfWeek));
   Wire.send(decToBcd(dayOfMonth));
   Wire.send(decToBcd(month));
   Wire.send(decToBcd(year));
   Wire.endTransmission();
}

// Gets the date and time from the ds1307
void getDateDs1307(byte *second,
          byte *minute,
          byte *hour,
          byte *dayOfWeek,
          byte *dayOfMonth,
          byte *month,
          byte *year)
{
  // Reset the register pointer
  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.send(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 7);

  // A few of these need masks because certain bits are control bits
  *second     = bcdToDec(Wire.receive() & 0x7f);
  *minute     = bcdToDec(Wire.receive());
  *hour       = bcdToDec(Wire.receive() & 0x3f);  // Need to change this if 12 hour am/pm
  *dayOfWeek  = bcdToDec(Wire.receive());
  *dayOfMonth = bcdToDec(Wire.receive());
  *month      = bcdToDec(Wire.receive());
  *year       = bcdToDec(Wire.receive());
}

void setup()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
  Wire.begin();
  Serial.begin(9600);

  // Change these values to what you want to set your clock to.
  // You probably only want to set your clock once and then remove
  // the setDateDs1307 call.
  second = 45;
  minute = 3;
  hour = 7;
  dayOfWeek = 5;
  dayOfMonth = 17;
  month = 4;
  year = 8;
  setDateDs1307(second, minute, hour, dayOfWeek, dayOfMonth, month, year);
}

void loop()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;

  getDateDs1307(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.print(second, DEC);
  Serial.print("  ");
  Serial.print(month, DEC);
  Serial.print("/");
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  Serial.print(year, DEC);
  Serial.print("  Day_of_week:");
  Serial.println(dayOfWeek, DEC);

  delay(1000);
}


Кода е етстван много пъти и работи.Дори съм го направил да изобразява часа на LCD дисплей и работи много добре.Пробвай.

Титла: Arduino Real Time
Публикувано от: tonivox в Февруари 09, 2012, 04:38:20 pm

Благодаря ти но при мен не тръгва. Аз съм с Ардуино 1.0 и явно библиотеките са други. И не ми тръгват някои неща. Какво би ме посъветвал ??? Да мина на по долна версия ???

Титла: Arduino Real Time
Публикувано от: emil74 в Февруари 09, 2012, 10:02:39 pm

Провери си хардуерната част.

Титла: Arduino Real Time
Публикувано от: reverenge в Февруари 14, 2012, 07:01:24 am

Щом имаш съмнения във версията свали си по-старата.Аз използвам и двете и не съм обърнал внимание с коя съм качвал кода,доколкото до библиотеките се използват същите.
  Когато за първи път си играех с RTC проблем ми беше ,че го правих на бреадбоард и заради лошите връзки не можех да прочета точния час.След като го прехвърлих на платка всичко тръгна нормално.Друго нещо което оказва положителен ефект е корпуса на кварца да се даде на маса.
  Ако имаш възможност смени DS1307 да не е дефектен или изгорял.